COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	title orig
C00005 ENDMK
C⊗;
title orig

a←←0
b←←1
c←←2
d←←3
e←←4
p←←17

start:	move c, [=1000000]
	movei a, hand
	movem a, jobapr↑
	move b,int
	intenb b,
	setzm count#
loop:
 	move b,s1
	aos count
	fmp  b,s2
	jumpe b,ok
comment ⊗
When the outstr is up here we get NON-ZERO RESULT (really!) a lot.
When it's down there we get NON-ZERO RESULT ↔ UNUSUAL INTERRUPT. ⊗
	jfcl
	jfcl
	jfcl
	jfcl
	outstr [asciz /
NON-ZERO RESULT/]
	jumpe b,ok
	outstr [asciz / (really!)/]
ok: ;;	outchr ["."]
	sojg c,loop
	exit 1,

hand:
	intmsk off
      	move a,jobtpc↑
	movem a, save
	uwait
	debreak
	setz b,
	move a,save
	tlne  a,100
	intdej int
	outstr	[asciz /
UNUSUAL INTERRUPT PC=/]
	rotc a,3
	addi b,"0"
	outchr b
	tro a,4
handl:	movei b,0
	rotc a,3
	jumpe a,hande
	addi b,"0"
	outchr b
	jrst handl

hande:	movei b,0
	movei a,ok
	movem a,save
	intdej int


s1:	1.0E-30
s2:	1.0E-30
int:	100
save:	0
off:	777777,,777677
DMP:	BLOCK 6
PATCH:	BLOCK 100
pdl:	block 100
	end start